AWK: 두 개의 키 열이 파일 간에 일치하는 경우 일치하지 않는 행을 유지하면서 한 파일의 열 16을 다른 파일의 일치하는 행에 추가합니다.

awk 스크립트는 좋은 시작이지만 상당히 사소한 문제를 해결해야 합니다.

1. OFS와 마찬가지로 출력 필드 구분 기호( )를 탭으로 설정해야 합니다 FS.
2. 새 열 헤더를 인쇄해야 합니다.
3. 일치하는 줄이 a[$2,$3]아닌 인쇄해야 합니다 .a[$16]
4. 일치하지 않는 행을 유지하려면 해당 행도 인쇄해야 하며, 모든 출력 행이 동일한 수의 열을 갖도록 빈 필드를 추가하는 것이 좋습니다.

예를 들어:

$ awk -F "\t" -v OFS='\t' '
  NR == FNR { a[$1,$2] = $5; next };

  FNR == 1     { c = "column 16" };
  ($2,$3) in a { c = a[$2,$3] };

  {
    print $0, c;
    c = ""
  }' FileB.tsv  FileA.tsv 
id      graph   circle  several columns...      length  column 16
196-0   196     0       ----    12874   TTCTAAAGTATAAAGCCTGTC...
195-1   195     1       ----    12874   CTTGCTTGAGCTGCTCTGCAA...
56-0    56      0       ----    3349
115-1   115     1       ----    5297

a[$1,$2]=$5FileB 예제 데이터에 필드가 5개만 있기 때문에 여기서는 이것을 사용하고 있습니다 . $16실제 데이터로 변경하세요 .

이는 변수를 사용하여 c추가할 열의 값을 보유합니다. 여기에는 새 열 이름, 빈 문자열 또는 일치하는 행의 열에 추가될 값이 포함됩니다. 각 출력 줄이 인쇄된 후 빈 문자열로 재설정됩니다.

cat -T참고로, 빈 필드는 일반적으로 보이지 않지만, 출력을 파이핑하여 일치하지 않는 행에 빈 필드가 추가되는지 확인할 수 있습니다. ^I해당 줄 끝에 (탭)이 표시됩니다.

하드코딩하는 대신 FileB.tsv의 첫 번째 행에서 열 이름을 가져오는 대체 버전:

$ awk -F "\t" -v OFS='\t' '
  NR == 1      { c = $5 ; next };
  NR == FNR    { a[$1,$2] = $5; next };
  ($2,$3) in a { c = a[$2,$3] };

  { print $0, c; c = "" }' FileB.tsv  FileA.tsv 

awk를 사용하십시오.

$ cat tst.awk
BEGIN {
    FS = OFS = "\t"
}
NR == FNR {
    val = $NF
    if ( FNR == 1 ) {
        hdr = val
    }
    else {
        map[$1 FS $2] = val
    }
    next
}
{
    if ( FNR == 1 ) {
        val = hdr
    }
    else {
        key = $2 FS $3
        val = (key in map ? map[key] : "----")
    }
    print $0, val
}

$ awk -f tst.awk FileB.tsv FileA.tsv
id      graph   circle  several columns...      length  Column16
196-0   196     0       ----    12874   TTCTAAAGTATAAAGCCTGTC...
195-1   195     1       ----    12874   CTTGCTTGAGCTGCTCTGCAA...
56-0    56      0       ----    3349    ----
115-1   115     1       ----    5297    ----

입력의 마지막 열이 아닌 경우 $NF다음으로 변경합니다.$16$16