Bash 스크립트에서 grep 사용 속도 향상

Question

현재 위치를 보여주기 위해 클라이언트와 서버라는 2개의 입력 파일을 보여주고 각 파일에서 ID를 찾을 수 있는 위치를 알려줍니다. 다음과 같이 awk를 사용하십시오.

$ cat tst.sh
#!/usr/bin/env bash

awk '
    (NR == FNR) && match($0,/\[MarketOrderTransitions[^]]+]/) {
        id = substr($0,RSTART+23,RLENGTH-24)
        print FILENAME, id
    }
    (NR > FNR) && match($0,/.*"orderId":"/) {
        id = substr($0,RLENGTH+1)
        sub(/".*/,"",id)
        print FILENAME, id
    }
' "$@"

$ ./tst.sh Server Client
Server a4ec2abf-059f-4452-b503-ae58da2ce1ff
Server a4ec2abf-059f-4452-b503-ae58da2ce1ff
Server a4ec2abf-059f-4452-b503-ae58da2ce1ff
Server a4ec2abf-059f-4452-b503-ae58da2ce1ff
Server a4ec2abf-059f-4452-b503-ae58da2ce1ff
Client a4ec2abf-059f-4452-b503-ae58da2ce1ff

또한 예상되는 출력이 옆에 숫자가 있는 비슷한 모양의 ID 목록이라고 말씀하셨지만 이러한 ID는 제공한 예제 입력과 관련이 없는 것 같고 숫자가 어디서 왔는지 알려주지 않았습니다.

귀하의 요구 사항을 표현하고 질문에 테스트 가능한 예를 제공할 수 있게 되면 이 스크립트를 완성할 수 있으며 이는 귀하의 셸 스크립트보다 훨씬 빠르게 실행될 것입니다.

당신이 하려는 일에 대한 한 가지 추측은 다음과 같습니다. GNU awk를 사용하여 시간 기능을 수행하는 것입니다:

$ cat tst.sh
#!/usr/bin/env bash

awk '
    { time = substr($0,2,26) }
    (NR == FNR) && match($0,/\[MarketOrderTransitions[^]]+]/) {
        id = substr($0,RSTART+23,RLENGTH-24)
        orders_time[id] = time
    }
    (NR > FNR) && match($0,/.*"orderId":"/) {
        id = substr($0,RLENGTH+1)
        sub(/".*/,"",id)
        time_diff = time2ms(time) - time2ms(orders_time[id])
        print id " -> " time_diff " ms"
    }

    function time2ms(time,      t,secs) {
        gsub(/[-:]/," ",time)
        split(time,t,/[.]/)
        return ( mktime(t[1]) substr(t[2],1,3) )
    }
' "$@"

$ ./tst.sh Server Client
a4ec2abf-059f-4452-b503-ae58da2ce1ff -> 149336 ms

하지만 귀하가 게시한 예상 출력은 귀하가 게시한 예제 입력과 관련이 없는 것 같아서 이것이 맞는지 모르겠습니다.

Answer 1