최소/최대/평균 거래 기간 계산 시 출력에서 가장 짧은 거래의 ID가 누락되었습니다.

Question

달성하려는 작업은 awk스크립트에서 완전히 수행할 수 있으며 이는 텍스트 처리에 셸 루프를 사용하는 것보다 훨씬 효율적입니다. 나는 다음 프로그램을 추천합니다(우리는 이것을 이라고 부릅니다 analyze_timing.awk):

#!/usr/bin/awk -f

function timediff(start,end,    stfld,endfld,diff) {
    split(start,stfld, /:/)
    split(end,  endfld,/:/)

    if (endfld[1]<stfld[1]) {
        diff=(3600*(endfld[1]+24) + 60*endfld[2] + endfld[3])
    }
    else {
        diff=(3600*endfld[1] + 60*endfld[2] + endfld[3])
    }

    diff -= (3600*stfld[1] + 60*stfld[2] + stfld[3])
    return diff
}


$5 ~ /^:\.+starting_transaction/ {laststart=$2;next}

$5 ~ /^:\.+ending_transaction/ {
    n_transact++
    duration=timediff(laststart, $2)
    avg+=duration
    
    if (n_transact==1) {
        shortest=duration
        longest=duration
        min_id=substr($4,2)
    }
    else {
        if (duration<shortest) {
            shortest=duration
            min_id=substr($4,2)
        } else if (duration>longest) {
            longest=duration
        }
    }
}

END {
    printf("avg: %f | max: %f | min: %f | minID: %d\n", avg/n_transact, longest, shortest, min_id)
}

timediff()예제에 표시된 대로 먼저 두 타임스탬프 사이의 경과 시간을 계산하는 함수를 정의합니다 . 단순화를 위해 트랜잭션이 24시간 이내에 완료된다고 가정합니다.

starting_transaction그런 다음 행의 5번째 필드가 a :및 임의의 숫자 로 시작하는지 확인 .하고 변수에 시간을 기록합니다 laststart. 다섯 번째 필드도 로 시작하는 경우 ending_transaction차이를 계산 laststart하고 최소/최대/평균을 계산하는 데 사용되는 변수를 채웁니다. 지금까지의 거래 중 가장 짧은 거래라면 ID가 에 기록됩니다 min_id.

마지막으로 프로그램은 필요에 따라 요약을 인쇄합니다.

당신은 그것을 부를 것입니다

awk -f analyze_timing.awk log-file.txt

Answer 1