셸 도구 awk를 사용하여 fslint|query|sed의 출력을 편집합니다.

내가 얼마나 많은 시간을 투자할 의향이 있는지를 고려하면 귀하의 요구 사항 목록을 이해할 수 없습니다. 그러나 다음은 귀하가 관심 있어 보이는 파일 형식을 정렬하고 인쇄하기 위한 스크립트입니다. 나머지는 귀하가 알아내실 수 있기를 바랍니다.

$ cat tst.awk
/^#/ { prt(); print; next }
{ files[$0] }
END { prt() }

function prt(   file, isLibrary, isLabsBack, isNothing) {
    for (file in files) {
        if ( file ~ /(^|\/)Library(\/|$)/ ) {
            isLibrary[file]
        }
        else if ( file ~ /(^|\/)(labs data|backup-current)(\/|$)/ ) {
            isLabsBack[file]
        }
        else {
            isNothing[file]
        }
    }
    for (file in isLibrary) {
        print "Library", file
    }
    for (file in isLabsBack) {
        print "LabsBack", file
    }
    for (file in isNothing) {
        print "Nothing", file
    }
    delete files
}

.

$ awk -f tst.awk file
#3 x 697,612,024        (1,395,236,864) bytes wasted
LabsBack /yet/another/path/to/labs data/some/path/file_a.dat
Nothing /another/path/to/backup-disk-name/171023/file_a.dat
Nothing /path/to/backup-100425/file_a.dat
#4 x 97,874,344 (293,634,048)   bytes wasted
Library /backup-120708/Library/some/path/file b.mov
LabsBack /some/other/path/to/backup-current/file b.mov
Nothing /path/to/backup-100425/file b.mov
Nothing /another/path/to/backup-140102/file b.mov
#2 x 198,315,112        (198,316,032)   bytes wasted
Nothing /path/to/backup-100425/file_c.out
Nothing /another/path/to/backup-disk-name/171023/file_c.out

관심 있는 사람들을 위해 질문에 언급된 원하는 출력을 제공하는 코드는 다음과 같습니다. 이것은 @Ed의 정말 스마트한 코드를 약간만 적용한 것입니다.

BEGIN { print "#!/bin/bash" }
/^#/ { prt(); print; next }
{ files[$0] }
END { prt() }

function prt(   file, isDate, isKeep, isDelete, backup, latest, pats) {
    # file exists in a current backup directory (yes|no)
    backup = "no"
    # latest historical backup date
    latest = "000000"
    for (file in files) {
        if ( file ~ /\/Library\// ) {
            # files to check manually
            isKeep[file]
        }
        else if ( file ~ /\/(labs data|backup-current)\// ) {
            # backup files to keep
            isKeep[file]
            backup = "yes"
        }
        else if ( match(file, /\/(backup-disk-name\/|backup-)([0-2][0-9][0-1][0-9][0-3][0-9])\//, pats) != 0 ) {
            # files in historical backup directories
            if ( pats[2] > latest ) {
                latest = pats[2]
            }
            isDate[file] = pats[2]
        }
        else {
            # unclassified files to check manually
            isKeep[file]
        }
    }
    for (file in isDate) {
        if ( isDate[file] == latest && backup == "no") {
            isKeep[file]
        }
        else {
            isDelete[file]
        }
    }
    for (file in isKeep) {
        print "#", file
    }
    for (file in isDelete) {
        # use single quotes to escape special characters in file
        # use gensub() to escape single quotes in file
        print "rm", "'" gensub(/'/,"'\\\\''", "g", file) "'"
    }
    delete files
}

마지막으로 몇 가지 생각을 공유하고 싶습니다. 너무 멀리 벗어나지 않았으면 좋겠습니다.
몇 주 전에 저는 마침내 그 거대한 백업을 정리하기로 결정했습니다(일부 파일에는 10개 이상의 중복이 있었습니다). 하지만 이 작업을 자동화하는 도구를 찾을 수 없습니다. 나는 이것을 위해 C 프로그램을 시작하고 싶지도 않고 Perl 방식으로 하고 싶지도 않습니다. 그래서 나는 쉘 루트로 가야 한다는 것을 알았습니다. 하지만 어디서부터 시작해야 할지 모르겠습니다. 첫 번째 줄에 갇혔습니다.

많이 읽은 후에도 여전히 혼란 스럽습니다. 그래서 SE에 질문을 게시하기로 결정했습니다.
@Ed의 코드를 처음 읽었을 때 "대체 뭐지!"라고 생각했습니다. 그러다가 그것을 받았을 때 그것이 효율적이고 명확한 훌륭한 코드라는 것을 깨달았습니다.

그래서 여기 있습니다. 약 일주일 전에 나는 awkRegExp에 대해 아무것도 모르고 거의 알지 못했습니다. 이제 @Ed의 기여 덕분에 "나의" 첫 번째 awk스크립트를 작성하고 RegExp 세계를 더 잘 이해하고 당면한 작업을 완료할 수 있었습니다 . 더 중요한 것은 이제 RegExp awk및 기타 텍스트 처리 셸 도구를 직접 살펴볼 만큼 자신감이 생겼다는 것입니다 . 이는 또한 제가 SE에 더 많이 기여하도록 동기를 부여합니다.
저처럼 산을 마주하는 등 어려운 상황에 처해 있는 분들에게 희망을 주고자 제 개인적인 경험을 공유하고 싶었습니다.