grep을 사용하여 Git 프로젝트에 소요된 시간 추정

다음 Perl 코드는 내가 생각하는 당신이 원하는 것에 매우 가깝습니다. Perl을 처음 사용하는 경우 DateTime::Format::StrptimeCPAN에서 이 모듈을 설치 해야 합니다 cpan install DateTime::Format::Strptime....

그런 다음 git log를 파일로 출력합니다 git log > git.log.

그 후, 다음 코드를 파일에 붙여넣고 로그 파일을 동일한 디렉터리에 배치한 후 실행합니다.

이것은 내 코드가 가장 예쁘거나 효율적인 코드는 아니지만 뭔가를 조합하는 데 몇 분 밖에 걸리지 않았습니다.

#!/usr/bin/perl
use warnings;
use strict;

use DateTime::Format::Strptime;

my $log = 'git.log';

open my $fh, '<', $log or die $!;

my %dates;
my @order;

while (<$fh>){
    if (/Date:\s+(.*?)(\d{2}:.*)/){
        push @order, $1 if ! $dates{$1};
        push @{ $dates{$1} }, "$1$2";
    }
}

my $letter = 'A';
my $total_time = DateTime::Duration->new;

for my $day (@order){

    my $start = $dates{$day}->[0];
    my $end   = $dates{$day}->[-1];

    my $parser = DateTime::Format::Strptime->new(
        pattern  => '%a %b %d %H:%M:%S %Y %z',
        on_error => 'croak',
    );

    my $dt1 = $parser->parse_datetime($start);
    my $dt2 = $parser->parse_datetime($end);

    my $total = $dt1 - $dt2;
    $total_time = $total_time + $total;

    print "$start\n$end\n";

    print "Total $letter:\t";
    print join ':', ($total->hours, $total->minutes, $total->seconds);
    print "\n\n";

    $letter++;
}

print "Total time overall: ";
print join ':', ($total_time->hours, $total_time->minutes, $total_time->seconds);
print "\n";