간단한 C 프로그램을 AWK 프로그램으로 변환해 보세요

$ awk '/Bond/{c++; print "There is a match on line " NR} END{print "\"Bond\" appeared " c " times in the file " FILENAME}' bond.txt
There is a match on line 1
There is a match on line 8
"Bond" appeared 2 times in the file bond.txt

어떻게 작동하나요?

awk는 모든 입력 라인을 암시적으로 반복합니다.

• /Bond/{c++; print "There is a match on line " NR}

  regex 와 일치하는 줄의 경우 Bond카운터가 c증가하고 일치가 발생한 줄을 보여주는 메시지가 인쇄됩니다. awk에서 지금까지 읽은 줄 수는 입니다 NR.

• END{print "\"Bond\" appeared " c " times in the file " FILENAME}

  마지막 줄을 읽은 후 총 일치 항목 수를 보여주는 메시지가 인쇄됩니다.

여러 줄 버전

코드를 여러 줄에 걸쳐 분산시키려는 경우:

awk '

/Bond/{
    c++
    print "There is a match on line " NR
}

END{
    print "\"Bond\" appeared " c " times in the file " FILENAME
}
' bond.txt

파일 요약 전에 파일 내용 표시

이 방법은 파일을 두 번 읽습니다. 처음에는 줄 번호로 형식이 지정된 파일 버전을 인쇄합니다. 두 번째 인쇄 요약 출력:

$ awk 'FNR==NR{printf("%5d) %s\n", NR,$0);next} /Bond/{c++; print "There is a match on line " FNR} END{print "\"Bond\" appeared " c " times in the file " FILENAME}' bond.txt{,}
    1) Secret agent Bond had been warned not to tangle with Goldfinger.
    2) But the super-criminal's latest obsession was too strong, too dangerous.
    3) He had to be stopped.
    4) Goldfinger was determined to take possession of half the supply of
    5) mined gold in the world--to rob Fort Knox!
    6) For this incredible venture he had enlisted the aid of the top
    7) criminals in the U.S.A, including a bevy of beautiful thieves from the
    8) Bronx. And it would take all of Bond's unique talents to make it fail--
    9) as fail it must.
There is a match on line 1
There is a match on line 8
"Bond" appeared 2 times in the file bond.txt

위 버전과 첫 번째 버전에는 두 가지 차이점이 있습니다. 먼저 bond.txt bond.txtbash를 사용하여 명령줄에 파일을 두 번 제공하거나버팀대 확장.bond.txt{,}​

둘째, 다음 명령을 추가했습니다.

FNR==NR{printf("%5d) %s\n", NR,$0);next}

FNR==NR이 명령은 NR이 지금까지 읽은 총 라인 수이고 FNR이 현재 파일에서 읽은 라인 수인 경우에만 실행됩니다. 그래서 그 당시 FNR==NR우리는 처음으로 파일을 읽고 있었습니다. 그런 다음 printf출력 형식을 지정하고 next스크립트의 나머지 명령을 건너뛰고 해당 줄로 이동합니다.

선택하다

이 버전에서는 파일을 한 번만 읽고, 형식화된 버전을 인쇄하고, 마지막에 인쇄할 요약 정보를 저장합니다.

$ awk '{printf("%5d) %s\n", NR,$0)} /Bond/{c++; s=s ORS "There is a match on line " FNR} END{print s; print "\"Bond\" appeared " c " times in the file " FILENAME}' bond.txt
    1) Secret agent Bond had been warned not to tangle with Goldfinger.
    2) But the super-criminal's latest obsession was too strong, too dangerous.
    3) He had to be stopped.
    4) Goldfinger was determined to take possession of half the supply of
    5) mined gold in the world--to rob Fort Knox!
    6) For this incredible venture he had enlisted the aid of the top
    7) criminals in the U.S.A, including a bevy of beautiful thieves from the
    8) Bronx. And it would take all of Bond's unique talents to make it fail--
    9) as fail it must.

There is a match on line 1
There is a match on line 8
"Bond" appeared 2 times in the file bond.txt

다음은 예제 C 코드의 기능을 복제해야 합니다.

#!/bin/awk -f
BEGIN{
    printf("Enter the name of a text file: ")
    getline file < "-"
    printf("Enter the pattern to search for: ")
    getline searchfor < "-"
    print "File contents:"
    while (getline < file){
        # NR does not work for files read with getline in this way, so....
        linenum++
        printf("%5d) %s\n",linenum,$0)
        if ($0 ~ searchfor){
            matchcount++
            matches=matches sprintf("There is a match on line %d\n",linenum)
        }
    }
    print matches
    printf("'%s' appeared %d times in file %s.\n",searchfor,matchcount,file)
}