☰

AWK - 행에서 최대값을 찾아 헤더와 함께 인쇄합니다.

tag-icon • tag-icon text-processing awk text
AWK - 행에서 최대값을 찾아 헤더와 함께 인쇄합니다.

sno#파일을 읽고 각 행에서 최대값을 찾은 다음 행의 ID, 최대값이 나오는 열( ) 및 연결된 열의 값을 인쇄해야 합니다 lc#. 최대값이 여러 번 발생하는 경우 일치하는 항목을 모두 포함해야 합니다. 예를 들어:

input.txt(탭으로 구분)

Id  sno1  lc1  sno2  lc2    sno3  lc3  sno4 lc4
RM1  98   ss1   88   ms1    78    gs1   45  rs1
RM2  23   ss2   44   ms2    98    gs2   15  rs2
RM3  45   ss3   100  ms3    33    gs3   10  rs3
RM4  45   ss4   45   ms4    12    gs4   11  rs4

출력.txt

RM1 ss1 sno1
RM2 gs2 sno3
RM3 ms3 sno2
RM4 ss4,ms4 sno1,sno2

답변1

입력하다

$ cat input.txt
Id  sno1  lc1  sno2  lc2    sno3  lc3  sno4 lc4
RM1  98   ss1   88   ms1    78    gs1   45  rs1
RM2  23   ss2   44   ms2    98    gs2   15  rs2
RM3  45   ss3   100  ms3    33    gs3   10  rs3
RM4  45   ss4   45   ms4    12    gs4   11  rs4

awk 스크립트

$ cat row_max.awk
NR == 1 {
        for (i = 1; i <= NF; i++) headers[i] = $i;
        next
}

{
        # find maximum value
        max = $2
        for (i = 4; i <= NF; i += 2) if ($i > max) max = $i;
        # print row id
        printf "%s", $1
        # print all lc# column values (assuming the column 
        # after the max value sno# column)
        sep = OFS
        for (i = 2; i <= NF; i += 2) {
                if ($i == max) {
                        printf "%s%s", sep, $(i + 1);
                        sep = ","
                }
        }
        # print all column headers of the max value columns
        sep = OFS
        for (i = 2; i <= NF; i += 2) {
                if ($i == max) {
                        printf "%s%s", sep, headers[i];
                        sep = ","
                }
        }
        printf "\n"
}

산출

$ awk -f row_max.awk input.txt
RM1 ss1 sno1
RM2 gs2 sno3
RM3 ms3 sno2
RM4 ss4,ms4 sno1,sno2

답변2

awk 'BEGIN{ getline; for(i=1;i<=NF;i++) hdr[i]=$i; max=-1 }
   { for(i=2; i<=NF; i+=2) 
        if($i==max) { lc=lc","$(i+1); sn=sn","hdr[i] }
        else if($i>max) { max=$i; lc=$(i+1); sn=hdr[i] }
     print $1" "lc" "sn; max=-1 }'

이 댓글이 달렸습니다

awk 'BEGIN{ 
       # read line 1 column-headers to an array 
       getline; for(i=1;i<=NF;i++) hdr[i]=$i
       # set max to less than zero 
       max=-1
     }
     { # processes lines 2 -> last
       # check each "sn.." field 
       for(i=2; i<=NF; i+=2) 
           if($i==max) { # this cannot occurr for 1st itteration per line  
                # append "lc" field value and "sn" header 
                #  to previous "lc" and "sn", using ","   
                lc=lc","$(i+1); sn=sn","hdr[i] 
            }
            else if($i>max) { # this must occurr on 1st itteration per line 
                # save "lc" field value and "sn" header  
                max=$i; lc=$(i+1); sn=hdr[i]  
            }
       # print output for the current line 
       print $1" "lc" "sn; 
       # set max to less than zero; ready for next line
       # max=-1 
     }

산출

RM1 ss1 sno1
RM2 gs2 sno3
RM3 ms3 sno2
RM4 ss4,ms4 sno1,sno2

관련 정보