☰

일치하는 열로 두 파일 결합

tag-icon • tag-icon awk join
일치하는 열로 두 파일 결합

파일 1.txt

    id                            No
    gi|371443199|gb|JH556661.1| 7907290
    gi|371443198|gb|JH556662.1| 7573913
    gi|371443197|gb|JH556663.1| 7384412
    gi|371440577|gb|JH559283.1| 6931777

파일 2.txt

 id                              P       R       S
 gi|367088741|gb|AGAJ01056324.1| 5       5       0
 gi|371443198|gb|JH556662.1|     2       2       0
 gi|367090281|gb|AGAJ01054784.1| 4       4       0
 gi|371440577|gb|JH559283.1|     21      19      2

출력.txt

 id                              P       R       S  NO
 gi|371443198|gb|JH556662.1|     2       2       0  7573913
 gi|371440577|gb|JH559283.1|     21      19      2  6931777

File1.txt에는 2개의 열이 있고 File2.txt에는 4개의 열이 있습니다. 고유한 ID를 가진 두 파일을 결합하고 싶습니다(배열[1]은 두 파일(file1.txt 및 file2.txt)에서 일치해야 함). 일치하는 ID 출력만 제공하고 싶습니다(output.txt 참조).

나는 열심히 노력했다 join -v <(sort file1.txt) <(sort file2.txt). awk 또는 Join 명령에 대한 도움을 요청합니다.

답변1

join좋은 결과:

$ join <(sort File1.txt) <(sort File2.txt) | column -t | tac
 id                           No       P   R   S
 gi|371443198|gb|JH556662.1|  7573913  2   2   0
 gi|371440577|gb|JH559283.1|  6931777  21  19  2

추신: 출력 열 순서가 중요합니까?

그렇다면 다음을 사용하십시오.

$ join <(sort 1) <(sort 2) | tac | awk '{print $1,$3,$4,$5,$2}' | column -t
 id                           P   R   S  No
 gi|371443198|gb|JH556662.1|  2   2   0  7573913
 gi|371440577|gb|JH559283.1|  21  19  2  6931777

답변2

그것을 사용하는 한 가지 방법 awk:

콘텐츠 script.awk:

## Process first file of arguments. Save 'id' as key and 'No' as value
## of a hash.
FNR == NR {
    if ( FNR == 1 ) { 
        header = $2
        next
    }   
    hash[ $1 ] = $2
    next
}

## Process second file of arguments. Print header in first line and for
## the rest check if first field is found in the hash.
FNR < NR {
    if ( $1 in hash || FNR == 1 ) { 
        printf "%s %s\n", $0, ( FNR == 1 ? header : hash[ $1 ] ) 
    }   
}

다음과 같이 실행하세요:

awk -f script.awk File1.txt File2.txt | column -t

결과는 다음과 같습니다.

id                           P   R   S  NO
gi|371443198|gb|JH556662.1|  2   2   0  7573913
gi|371440577|gb|JH559283.1|  21  19  2  6931777

관련 정보