설치하려는 마운트 지점에 대한 필수 마운트 지점을 어떻게 자동으로 설치합니까?

Question

구체적으로 전체 FS가 아닌 FS의 "home" 하위 디렉터리를 LABEL=XYZ에 마운트하려는 경우 다음과 같은 줄을 추가할 수 있습니다./newplace/mypath

LABEL=XYZ /newplace subdir subdir=main,srctype=vfat,noauto,... 0 0

그리고 다음과 같은 스크립트로 /sbin/mount.subdir도우미( 직접 의미하지 않고 호출됨 )를 만듭니다.mount /newplace

#! /bin/zsh -p
(( EUID == 0 )) || exec sudo -- "$0" "$@"
PATH=/bin:/sbin:/usr/bin:/usr/sbin

# mount -t subdir -o subdir=foo -o otheroption source /dest calls us
# as mount.subdir source /dest -o rw,subdir=foo,otheroption
dev=${1?} dest=${2?} opts=( ${(s[,])4?} )

# extract mandatory subdir option
(( i = $opts[(I)subdir=*] )) || exit
subdir=${opts[i]#*=}
opts[i]=()

# extract optional srctype option
if (( i = $opts[(I)srctype=*] )); then
  type=(-t "$opts[i]")
  opts[i]=()
else
  type=()
fi

tmpdir=$(mktemp -d) || exit

mounted()true
if
  mount "$type[@]" -o "${(j[,])opts}" -- "$dev" "$tmpdir"
then
  mount --bind -- "$tmpdir/$subdir" "$dest" || mounted()false
  umount -- "$tmpdir"
fi && rmdir -- "$tmpdir" && mounted

전체 FS를 tmpdir에 마운트하고 하위 디렉터리를 대상 위치에 바인드 마운트한 다음 tmpdir을 마운트 해제하고 삭제합니다.

이후 편집에서 명확히 설명한 것처럼 실제로 마운트하고 싶고 /newplace하위 디렉터리에 FS를 마운트하려는 최종 목표를 향한 중간 단계가 아닌 유사한 접근 방식을 취할 수 있으며 이는 더 쉬워집니다. 필요한 파일 시스템을 마운트하는 도우미 프로그램:/mypath/mypath/myplace

LABEL=XYZ /mypath vfat noauto,[...]
/myplace/main /newplace prereq prereq=/myplace,noauto,... 0 0

/sbin/mount.prereq다음과 같은 스크립트로 도우미를 만듭니다 .

#! /bin/zsh -p
(( EUID == 0 )) || exec sudo -- "$0" "$@"
PATH=/bin:/sbin:/usr/bin:/usr/sbin

src=${1?} dst=${2?} opts=( ${(s[,])4?} )

# extract prereq options
for prereq in ${(M)opts:#prereq=*}; do
  prereq=${prereq#*=}
  mountpoint -q -- $prereq ||
    mount -- $prereq ||
    exit
done
opts=(${opts:#prereq=*})

exec mount --bind -o "${(j[,])opts}" -- "$src" "$dst"

를 제거한 /mypath후에는 자동으로 제거되지 않습니다 ./newplace

POSIX 쉘과 동일한 구문(그래서 에서도 작동해야 함 bash)은 다음과 같습니다.

#! /bin/sh -
[ "$(id -u)" -eq 0 ] || exec sudo -- "$0" "$@"
PATH=/bin:/sbin:/usr/bin:/usr/sbin

src="${1?}" dst="${2?}"

set -o noglob
IFS=,
set -- ${4?}

# extract prereq options
for opt do
  case $opt in
    (prereq=*)
      prereq=${opt#*=}
      mountpoint -q -- "$prereq" ||
        mount -- "$prereq" ||
        exit
      ;;
    (*)
      set -- "$@" "$opt"
  esac
  shift
done
opts="$*"

exec mount --bind -o "$opts" -- "$src" "$dst"

(검증되지 않은).

당신이 할 수 없다면편집하다스크립트를 계측할 수 있습니다. 예를 들어, 다음과 같이 작성되면 다음 bash과 같이 호출됩니다.

bash -c '
  mount() {
    if [[ $1 = "/newplace" ]]; then
      command mount /mypath || return
    fi
    command mount "$@"
  }
  export -f mount
  exec "$0" "$@"' your-script its args

또는 에 작성된 경우 zsh다음을 추가 ~/.zshenv(또는 해당 스크립트에 대해 설정 /some/dir/.zshenv)합니다.ZDOTDIR=/some/dir

if [[ $ZSH_SCRIPT:P = /path/to/your-script ]]; then
  mount() {
    if [[ $1 = /newplace ]]; then
      command mount /mypath || return
    fi
    command mount "$@"
  }
fi

또는 모든 쉘에 대해 동일한 작업을 수행하는 스크립트를 추가하십시오 mount./some/dir

#! /bin/sh -
if [ "$1" = /newplace ]; then
  /bin/mount /mypath || exit
fi
exec /bin/mount "$@"

스크립트를 호출합니다.

PATH="/some/dir:$PATH" your-script its args

Answer 1