☰

For 루프 - 배열 이름에 반복자를 사용하여 배열에 추가

tag-icon • tag-icon variable array for bash-array
For 루프 - 배열 이름에 반복자를 사용하여 배열에 추가

다음 질문이 있습니다. 일부 값을 포함하는 배열이 있습니다 arr. 각 값을 서로 다른 선언된 배열 집합 earr$j, 즉 arr[0]into earr1, arr[1]into earr2및 일반적으로 arr[j-1]into 로 정렬하고 싶습니다 earr$j. (나중에 s와 같은 요소를 target s의 다음 요소 arr로 추가하겠습니다 ). earr$j나는 다음 코드 조각(더 큰 코드 조각의 일부)을 사용하여 이 작업을 수행하려고 합니다.

for j in $(seq 1 $number_of_elements); do earr$j+=(${arr[j-1]}); done

내가 만들 것 같다는 말을 들었습니다(내 게시물 "https://unix.stackexchange.com/questions/675454/for-loop-and-appending-over-list-of-arrays" 참조). 2차원 배열(Bash에서는 지원되지 않음) 나는 Bash 구문을 부적절하게 사용한 결과에 관계없이 이것이 내 의도가 아니라는 점을 강조합니다. 내 이전 게시물에서 이 문제를 제대로 설명하지 못했기 때문에 다시 게시합니다.

답변1

질문에 문자 그대로 대답하려면 일반적으로 다음과 같이 작동합니다 eval.

for i in "${!arr[@]}"; do
  eval '
    earr'"$i"'+=( "${arr[i]}" )
  '
done

eval위험하지만 올바르게 사용하면 안전합니다. 오류 위험을 제한하는 좋은 방법은 확실히 확장이 필요한 부분을 제외하고 모든 것을 작은따옴표로 묶고 작은따옴표 안에 있지 않은 부분(여기서는 $i큰따옴표이며 내용으로 확장됩니다) 을 확인하는 것입니다. 변수의 i)은 완전히 귀하의 통제하에 있습니다. 이 경우에는 $i숫자만 포함된다는 것을 알고 있으므로 이는 eval쉘 코드로 평가되는 임의의 데이터가 아닙니다(반대로 ${arr[i]}작은 따옴표를 생략하고 싶지는 않을 것입니다).

왜 2차원 배열이 부적절하다고 말씀하시는지 아직도 이해가 되지 않습니다. ksh93( bashksh93의 구문 대부분을 복사했지만 다차원 배열은 복사하지 않음) 에서 다음을 수행할 수 있습니다.

for i in "${!arr[@]}"; do
  earr[i]+=( "${arr[i]}" )
done

어쨌든 쉘을 사용해야 하는 특별한 이유가 없다면 @cas의 말에 동의합니다 perl. python.

답변2

다음은 Perl 및 HoAoA(Hash of Arrays) 데이터 구조를 사용하여 설명하는 작업을 수행하는 방법에 대한 예입니다.

이를 이해하는 데 도움이 되도록 다음 매뉴얼 페이지가 유용합니다: perldata(perl 데이터 유형), perldsc(데이터 구조), perllol(lol = 목록 목록), perlref(참조 자료) 및 perlreftut(참조 튜토리얼). 또는 perldoc같은 명령을 사용하여 perldoc -f opendir특정 Perl 기능에 대한 자세한 정보를 얻을 수도 있습니다 perldoc -f grep.

스크립트에 사용된 sort합계는 grep내장된 Perl 함수라는 점에 유의하세요. 그들은아니요sort및 명령줄 도구 grep... 원하는 경우 Perl에서 이러한 도구를 호출할 수 있습니다(백틱이나 qx따옴표, system()함수 또는 open()파이프를 여는 함수를 사용하는 등 여러 가지 방법을 사용함). 이 모든 내용과 그 이상에 대한 자세한 내용을 확인하세요 perldoc.

$ cat HoAoA.pl 
#!/usr/bin/perl

use strict;
use Data::Dump qw(dd);

# $h is a ref to Hash-of-Array-ofArrays (HoAoA).
#
# This will be a data structure with the directory names
# (Folder1, Folder2, Folder3) as the hash keys of the top-level
# hash.  Each element of that hash will be an array where the
# indexes are the line numbers of the data.txt files in each
# of those directories. The data in these second-level arrays
# will be an array containing the three values in each line of
# data.txt: $$h{directory}[line number][element]
my $h;

# get the directory name from the first command line arg, default to ./
my $dir = shift // './';

# get a list of subdirectories that contain 'data.txt',
# excluding . and ..
opendir(my $dh, "$dir") || die "Couldn't open directory $dir: $!\n";
my @dirs = sort grep { $_ !~ /^\.+$/ && -d $_ && -f "$_/data.txt" } readdir($dh);
closedir($dh);

dd \@dirs;   # Data::Dump's dd function is great for showing what's in an array
print "\n";

foreach my $d (@dirs) {
  my $f = "$d/data.txt";
  open(my $fh,"<",$f) || die "Couldn't open file $f: $!\n";
  my $lc=0;  # line counter
  while(<$fh>) {
    chomp;   # strip trailing newline char at end-of-line
    my @row = split /\s*,\s*/;   # assume simple comma-delimited values
    push @{ $$h{$d}[$lc++] }, @row;
  }
  close($fh);
}

# dd is even better for showing complex structured data
dd $h;
print "\n";

# show how to access individual elements, e.g. by changing the
# zeroth element of line 0 of 'Folder1' to 999.
$$h{'Folder1'}[0][0] = 999;

dd $h;
print "\n";

# show how to print the data without using Data::Dump
# a loop like this can also be used to process the data.
# You could also process the data in the main loop above
# as the data is being read in.
foreach my $d (sort keys %{ $h }) {   # `foreach my $d (@dirs)` would work too
  print "$d/data.txt:\n";
  foreach my $lc (keys @{ $$h{$d} }) {
    print "  line $lc: ", join("\t",@{ $$h{$d}[$lc] }), "\n";
  }
  print "\n";
}

참고: 위의 내용은 간단한 쉼표로 구분된 데이터 파일을 처리하기 위해 작성되었습니다. 모든 특이성과 복잡성(예: 쉼표가 포함된 여러 줄의 큰따옴표 필드)이 있는 실제 CSV의 경우 다음을 사용합니다.텍스트::CSV기준 치수. 이는 핵심 Perl 배포판에 포함되지 않은 타사 라이브러리 모듈입니다. Debian 및 관련 배포판에서는 apt-get install libtext-csv-perl libtext-csv-xs-perl. 또는 cpan(perl 코어에 포함된 라이브러리 모듈 설치 및 관리 도구)를 사용하여 설치할 수 있습니다.

또한 참고: 위의 스크립트는데이터::덤프. 이는 구조화된 데이터를 덤프하는 데 사용할 수 있는 타사 모듈입니다. 불행히도 Perl 코어 라이브러리에는 포함되어 있지 않습니다. 데비안 apt-get install libdata-dump-perl등에서 다른 배포판도 비슷한 패키지 이름을 갖습니다. 그리고 최후의 수단으로 cpan.

어쨌든 다음 폴더 구조와 data.txt 파일을 사용합니다.

$ tail */data.txt
==> Folder1/data.txt <==
1,2,3
4,5,6
7,8,9

==> Folder2/data.txt <==
7,8,9
4,5,6
1,2,3

==> Folder3/data.txt <==
9,8,7
6,5,4
3,2,1

HoHoA.pl 스크립트를 실행하면 다음과 같은 출력이 생성됩니다.

$ ./HoAoA.pl 
["Folder1", "Folder2", "Folder3"]

{
  Folder1 => [[1, 2, 3], [4, 5, 6], [7, 8, 9]],
  Folder2 => [[7, 8, 9], [4, 5, 6], [1, 2, 3]],
  Folder3 => [[9, 8, 7], [6, 5, 4], [3, 2, 1]],
}

{
  Folder1 => [[999, 2, 3], [4, 5, 6], [7, 8, 9]],
  Folder2 => [[7, 8, 9], [4, 5, 6], [1, 2, 3]],
  Folder3 => [[9, 8, 7], [6, 5, 4], [3, 2, 1]],
}

Folder1/data.txt:
  line 0: 999   2       3
  line 1: 4     5       6
  line 2: 7     8       9

Folder2/data.txt:
  line 0: 7     8       9
  line 1: 4     5       6
  line 2: 1     2       3

Folder3/data.txt:
  line 0: 9     8       7
  line 1: 6     5       4
  line 2: 3     2       1

관련 정보