☰

awk를 사용하여 동일한 행의 중복 값을 제거하는 방법은 무엇입니까?

tag-icon • tag-icon text-processing awk deduplication
awk를 사용하여 동일한 행의 중복 값을 제거하는 방법은 무엇입니까?

같은 행에서 중복된 열/필드를 제거하고 싶습니다. 시도해 보았지만 중첩된 루프, 조건문 및 배열이 포함된 긴 코드가 작동하지 않는 결과가 나왔습니다.

  • 입력 데이터: 
    1 2 3 4
1 2 3 1
1 2 1 3
4 4 3 2
3 3 3 2
1 1 1 1
5 2 2 7
  • 원하는 출력: 
    1 2 3 4
1 2 3 
1 2 3
4 3 2
3 2
1
5 2 7

답변1

사용 awk:

awk '{
    for(i=1; i<=NF; i++)
        printf "%s", (!seen[$i]++? (i==1?"":FS) $i: "" )
    delete seen; print ""
}' infile

답변2

awk '{
    for (i=1; i<=NF; i++) {
        if ( !seen[NR,$i]++ ) {
            printf "%s%s", (i>1 ? OFS : ""), $i
        }
    }
    print ""
}' file
1 2 3 4
1 2 3
1 2 3
4 3 2
3 2
1
5 2 7

답변3

awk '
{
  split($0,a); $0=""
  for (i=j=1; i in a; i++)
    if (!(index(FS $0 FS,FS a[i] FS)))
      $(j++) = a[i]
}1' file

산출:-

1 2 3 4
1 2 3
1 2 3
4 3 2
3 2
1
5 2 7

perl -lane 'my %h;
  print join $", grep { !$h{$_}++ } @F;
' file

GNU sed를 사용하고 확장 정규식 모드를 켜십시오 -E.

sed -Ee '
  s/.*/ & /;ta
  :a
    s/( (\S+) (.* )?)\2 /\1/
  ta
  s/ (.*) /\1/
' file

답변4

대부분 다른 답변과 유사하지만 "현재 레코드"를 다시 작성하고 1마지막에 그런 식으로 인쇄합니다.

awk '
    {
        delete seen
        nf = 0

        for (i = 1; i <= NF; ++i)
            if (!seen[$i]++)
                field[++nf] = $i

        $0 = ""

        for (i = 1; i <= nf; ++i)
            $i = field[i]
    }; 1' file

다시 말하지만 루프를 제거하려면(를 호출하여 암시적으로 만듭니다 split()):

awk '
    {
        delete seen
        nf = split($0, fields)

        $0 = ""

        for (i = 1; i <= nf; ++i)
            if (!seen[fields[i]]++)
                $(NF+1) = fields[i]
    }; 1' file

관련 정보