☰

gnuplot은 특정 DPI에 대해 이미지 너비를 픽셀로 설정합니다.

tag-icon • tag-icon gnuplot
gnuplot은 특정 DPI에 대해 이미지 너비를 픽셀로 설정합니다.

gnuplot을 사용하여 이미지를 생성하고 다음 가이드를 제공해야 합니다.

너비 = 90mm(255pt), 300dpi 픽셀 = 1063, 500dpi 픽셀 = 1772, 1000dpi 픽셀 = 3543

사용 중인 gnuplot에서 300dpi에 대해 너비 = 90mm 및 픽셀 = 1063의 이미지를 생성하려면 어떻게 해야 합니까?

set terminal pngcairo size 420,768

그러나 x와 y를 원하는 너비와 픽셀로 변환하는 방법

답변1

솔루션 1

정확히 420x768 크기의 그래픽을 만들었다고 가정합니다. 그래픽의 모양을 변경하지 않고 너비가 1063픽셀(300dpi에서 90mm)인 PNG 이미지를 생성하려면 다음 설정을 지정하십시오.

scale = 1063.0/420.0

set terminal pngcairo size 420*scale,768*scale fontscale scale linewidth scale pointscale scale

# PLOT HERE

이 설정에서는 그래픽의 너비와 높이에 1063.0/420.0 = 2.53을 곱하고 글꼴 크기, 선 너비 및 포인트 크기가 동일한 요소로 조정됩니다.

솔루션 2

주어진 DPI를 사용하여 처음부터 그래프를 작성하려면 다음 터미널 설정은 어떻습니까?

dpi = 300 ## dpi (variable)
width = 90 ## mm (variable)
height = 164.5 ## mm (variable)

in2mm = 25.4 # mm (fixed)
pt2mm = 0.3528 # mm (fixed)

mm2px = dpi/in2mm
ptscale = pt2mm*mm2px
round(x) = x - floor(x) < 0.5 ? floor(x) : ceil(x)
wpx = round(width * mm2px)
hpx = round(height * mm2px)

set terminal pngcairo size wpx,hpx fontscale ptscale linewidth ptscale pointscale ptscale

# PLOT HERE

height원본 그래픽의 종횡비를 유지하려면 764.0/420.0*90 계산을 사용하십시오.

관련 정보