☰

줄 번호를 기준으로 파일에 열 추가

tag-icon • tag-icon text-processing awk sed paste
줄 번호를 기준으로 파일에 열 추가

다른 파일의 끝에 마지막 열로 추가하고 싶은 숫자 목록이 있습니다.

1:.196
5:.964
6:.172

앞의 숫자(1, 5, 6)는 대상 파일의 어느 줄에 이 숫자를 추가해야 하는지를 나타내므로 첫 번째 줄이 끝나고 .196다섯 번째 줄이 끝나는 .964식입니다. paste file1 file2줄 번호는 일반적 으로 고려되지 않으며 다섯 번째 줄 끝이 아닌 1:.196첫 번째와 두 번째 줄 끝에 .964추가 됩니다. 이 작업을 올바른 방법으로 수행하는 방법에 대한 아이디어가 있습니까?

이는 다음과 같이 예상됩니다.

Lorem Ipsum 1238 Dolor Sit 4559.196
Lorem Ipsum 4589 Sit elitr 1234
Lorem Ipsum 3215 Dolor Sit 5678
Lorem Ipsum 7825 Dolor Sit 9101
Lorem Ipsum 1865 Dolor Sit 1234.964

답변1

그리고 awk:

# create two test files
printf '%s\n' one two three four five six > target_file
printf '%s\n' 1:.196 5:.964 6:.172 > numbers

awk -F':' 'NR==FNR{ a[$1]=$2; next } FNR in a{ $0=$0 a[FNR] }1' numbers target_file

산출:

one.196
two
three
four
five.964
six.172

설명하다:

awk -F':' '      # use `:` as input field separator
  NR==FNR {      # if this is the first file, then...
    a[$1]=$2     # save the second field in array `a` using the first field as index
    next         # stop processing, continue with the next line
  }                         
  FNR in a {     # test if the current line number is present in the array
    $0=$0 a[FNR] # append array value to the current line 
  }
  1              # print the current line
' numbers target_file

답변2

$ sed 's/:/s:$:/;s/$/:/' nums_file |
  sed -f - file

설명하다:

° use the number file to create the sed commands to operate on the actual data
° Pass these sed commands over the pipe and use sed to apply them on the data file.

관련 정보