공통 데이터 파일에서 별도의 테이블 출력을 만들고 일부 합계를 계산합니다.

편집하다:

에드 모튼의 답변더 나은 방법은 그것을 사용하는 것입니다.

awk 'function print_entry(a,b,c,d) {
    k=split(c, ce, " ")
    split(d, dn, " ")
    for(i=1; i<=k; i++) {
        if(i%50==1) printf("\f%s\n%s\n%s\n%s\n",
            "PERSONS HAVING OUTSTANDING ADVANCE SALARY",
            "+==============================+",
            "|Sr.|   name   |Amount Rs.|Nos |",
            "+==============================+")
        printf("|%3s|%10s|%10.2f|%4d|\n",i,a,ce[i],dn[i])
    }
    print "================================"
    print "Total for",a,k,b
    print "================================"
    printf("\f")
}
BEGIN {FS="|"}
{
    if($1==name) {
        total+=$2
        entry=(entry " " $2)
        nos=(nos " " $3)
    }
    else {
        if(name) print_entry(name,total,entry,nos)
        name=$1
        total=$2
        entry=$2
        nos=$3
    }
}
END {if(name) print_entry(name,total,entry,nos)}' data.txt

주요 논리:

• 이름과 관련된 정보 수집 ( $1)
  • total$2각 항목을 합산하세요.
  • entry$2각 항목의 목록을 유지
  • nos$3각 항목의 목록을 유지
• 이름이 변경될 때마다 수집된 정보를 인쇄합니다.
  • 해당 이름에 대한 항목 수를 고려하여 항목 목록을 분할합니다 $2. 목록도 분할됩니다(항목 수가 동일해야 함).k$3
  • 1( i=1)부터 시작하여 각 항목을 인쇄합니다.
  • i mod 50제목을 인쇄하는 경우 1- 항목 50개마다 새 제목이 인쇄됩니다.
  • 그런 다음 합계를 인쇄하십시오.

• 이 함수를 사용하면 print_entry주요 연산이 더 명확하고 읽기 쉬워지며 연산에서 다시 사용되므로 END함수로 정의하면 반복 연산이 절약됩니다.

$ cat tst.awk
BEGIN { FS="|" }
$1 != prev {
    if ( NR>1 ) {
        prtTail()
    }
    prtHead()
    srval = 0
    tot   = 0
    prev  = $1
}
{
    tot += $2
    printf "|%3s|%10s|%10.2f|%4d|\n", ++srval, $1, $2, $3
}
END { prtTail() }

function prtHead() {
    print "PERSONS HAVING OUTSTANDING ADVANCE SALARY"
    print "+==============================+"
    print "|Sr.|   name   |Amount Rs.|Nos |"
    print "+==============================+"
}

function prtTail() {
    print "================================"
    printf "Total for %s %d %d\n", prev, srval, tot
    print "================================"
    print ""
}

.

$ awk -f tst.awk file
PERSONS HAVING OUTSTANDING ADVANCE SALARY
+==============================+
|Sr.|   name   |Amount Rs.|Nos |
+==============================+
|  1|   Kalpesh|    100.00|   1|
|  2|   Kalpesh|    500.00|   1|
================================
Total for Kalpesh 2 600
================================

PERSONS HAVING OUTSTANDING ADVANCE SALARY
+==============================+
|Sr.|   name   |Amount Rs.|Nos |
+==============================+
|  1|    Ramesh|    500.00|   1|
|  2|    Ramesh|    500.00|   1|
|  3|    Ramesh|    500.00|   1|
================================
Total for Ramesh 3 1500
================================

PERSONS HAVING OUTSTANDING ADVANCE SALARY
+==============================+
|Sr.|   name   |Amount Rs.|Nos |
+==============================+
|  1|    Naresh|    500.00|   1|
================================
Total for Naresh 1 500
================================

PERSONS HAVING OUTSTANDING ADVANCE SALARY
+==============================+
|Sr.|   name   |Amount Rs.|Nos |
+==============================+
|  1|    Ganesh|    500.00|   1|
|  2|    Ganesh|    500.00|   1|
|  3|    Ganesh|    500.00|   1|
|  4|    Ganesh|    500.00|   1|
================================
Total for Ganesh 4 2000
================================