☰

CSV 파일의 단일 열 전치

tag-icon • tag-icon shell-script shell
CSV 파일의 단일 열 전치

두 개의 열이 있는 CSV 파일이 있습니다. 즉, 첫 번째 열: 파일 이름 두 번째 열: 액세스 상태

다음은 몇 가지 예시 레코드입니다.

FileA, CREATE
FileA, MODIFY
FileA, DELETE
FileB, CREATE
FileB, MODIFY

첫 번째 열의 서로 다른 값을 기준으로 두 번째 열의 값을 단일 행으로 변환해야 합니다.

FileA, CREATE|MODIFY|DELETE
FileB, CREATE|MODIFY

답변1

또한 시도

awk '
$1 != LAST      {printf "%s%s ", LD, $1         # print every new COL1 value
                 LAST = $1                      # and remeber it
                 LD = RS                        # set the line delimiter (empty at program start)
                 FD = ""                        # unset field delimiter
                }
                {printf "%s%s", FD, $2          # print successive second fields, after field delim 
                 FD = "|"                       # set the field delimiter
                }
END             {printf RS                      # last action: new line
                }
' file
FileA, CREATE|MODIFY|DELETE
FileB, CREATE|MODIFY

답변2

명령 순서에 신경 쓰지 않으면 다음을 사용할 수 있습니다.

$ awk -F"[, ]" '{
            a[$1][$2]++
           }
           END{
            for(i in a){
                printf "%s,",i; 
                for(k in a[i]){
                    printf  "%s|", k
                }
                print ""
                }
            }' file | sed 's/|$//'
FileA, DELETE|CREATE|MODIFY
FileB, CREATE|MODIFY

이 순서가 필요한 경우 Perl 마법을 적용할 수 있습니다.

$ sed 's/ //' file | 
    perl -F, -lne 'push @{$k{$F[0]}},$F[1]; }{ 
    print "$_, ",join "|", @{$k{$_}} for keys(%k);' 
FileB, CREATE|MODIFY
FileA, CREATE|MODIFY|DELETE

답변3

awk '1 {if (a[$1]) {a[$1] = a[$1]" "$2"|"} else {a[$1] = $2"|"}} END {for (i in a) { print i,a[i]}}' file |sed 's/.$//'

답변4

GNU awk를 사용하여 정렬된 순서로 출력

gawk -F', ' '
    { a[$1] = a[$1] "|" $2 }
    END {
        PROCINFO["sorted_in"] = "@ind_str_asc"
        for (b in a) print b ", " substr(a[b], 2)
    }
'

키의 원래 순서대로 출력하려면 다음을 수행하십시오.

awk -F', ' '
    !($1 in a) { keys[++count] = $1 }
    { a[$1] = a[$1] "|" $2 }
    END {
        for (i = 1; i <= count; i++)
            print keys[i] ", " substr(a[keys[i]], 2)
    }
'

관련 정보