여러 부동 소수점 열의 합계를 계산하는 방법

Question 1

처음에는 쉘에서 이 작업을 수행하지 마십시오. 그러나 awk.쉘에서는 부동 소수점 연산을 수행하는 방법을 모릅니다.

귀하의 스크립트는 구문 분석할 파일 이름과 고려할 필드 이름에 해당하는 매개변수 세트를 사용하는 것으로 보입니다.

awk각 열에 대해 두 번 호출하는 것보다 더 효율적으로 이 작업을 수행할 수 있습니다.

BEGIN { OFS = FS = "|" }

FNR == 1 {
        # Handle the header row. Assuming "cols" is a FS-separated
        # string of column names that we want to sum, pick out the
        # column numbers that we want to process and put them in the
        # array "col". This also converts the "cols" string into a
        # corresponding "header" array.

        nf = split(cols, header)
        for (i = 1; i <= NF; ++i)
                for (j = 1; j <= nf; ++j)
                        if ($i == header[j])
                                col[j] = i
        next
}

{
        # Sum each column that we have enumerated in the "col" array.

        for (i = 1; i <= nf; ++i)
                sum[i] += $(col[i])
}

END {
        # Output a two row table containing only the headers that we
        # have summed over and the accumulated sums.

        $0 = ""

        for (i = 1; i <= nf; ++i)
                $i = header[i]
        print

        for (i = 1; i <= nf; ++i)
                $i = sum[i]
        print
}

다음을 사용하여 첫 번째 파일에서 이 명령을 실행하세요.

$ awk -v cols="SAL|COST|PER|TAG" -f script.awk file1
SAL|COST|PER|TAG
155|162|95|210

동일한 열을 두 번 나열하면 두 가지 합계가 발생합니다.

$ awk -v cols="SAL|SAL" -f script.awk file1
SAL|SAL
155|155

두 번째 파일에서:

$ awk -v cols="SAL|COST|PER|TAG" -f script.awk file2
SAL|COST|PER|TAG
55.018|314.686|222.12|359.303

사용 후 처리 column -t:

$ awk -v cols="SAL|COST|PER|TAG" -f script.awk file2 | column -s '|' -t
SAL     COST     PER     TAG
55.018  314.686  222.12  359.303

이것을 간단한 스크립트에 넣으십시오.

#!/bin/sh

infile=$1
shift

IFS='|'

awk -v cols="$*" -f script.awk "$infile" |
column -s '|' -t

다음과 같이 사용할 수 있습니다.

$ ./script.sh file1 PER TAG
PER  TAG
95   210

CSVkit과 같은 CSV 인식 도구를 사용하여 작업을 수행할 수도 있습니다.

csvstatCSV 파일에 대한 몇 가지 기본 "통계"를 계산하는 기능. 파일이 올바른 형식의 CSV 파일이라고 가정하면(각 데이터 행에 후행 |구분 기호가 있으므로 그렇지 않음) 각 열의 합계가 전달될 수 있습니다.

$ csvstat --sum file1
  1. ID: None
  2. NAME: None
  3. SAL: 155
  4. COST: 162
  5. PER: 95
  6. TAG: 210

$ csvstat --sum file2
  1. ID: None
  2. NAME: None
  3. SAL: 55.018
  4. COST: 314.686
  5. PER: 222.12
  6. TAG: 359.30278

또는 단일 열의 경우:

$ csvstat --sum -c 'SAL' file2
55.018

Answer